Migrated to Maven Central for publishing

Author: sluehr

.buildkite/pipeline.yml

@@ -27,9 +27,10 @@ steps:
 
   - label: ':rocket: publish'
     <<: *if-release
-    key: bintray-publish
+    key: mavencentral-publish
     agents:
       java: 11
     commands:
       - git fetch --tags
-      - ./gradlew bintrayPublish bintrayUpload --console plain
+      - ./gradlew publishReleasePublicationToMavenCentralRepository --console plain
+

build.gradle

@@ -3,7 +3,7 @@ plugins {
     id 'java-library'
     id 'io.freefair.lombok' version '5.1.1'
     id 'maven-publish'
-    id 'com.jfrog.bintray' version '1.8.4'
+    id 'signing'
     id 'io.spring.dependency-management' version '1.0.10.RELEASE'
     id 'com.github.jk1.dependency-license-report' version '1.14'
     id 'org.sonarqube' version '3.1.1'
@@ -13,23 +13,13 @@ plugins {
 apply plugin: 'io.freefair.lombok'
 apply plugin: 'idea'
 
-repositories {
-    mavenCentral()
-}
-
 group = 'engineering.everest.starterkit'
 sourceCompatibility = '1.11'
-version = gitVersion()
-
-test {
-	useJUnitPlatform()
-}
 
-lombok {
-    version = '1.18.16'
-    generateLombokConfig.enabled = false
-    config['lombok.addLombokGeneratedAnnotation'] = 'true'
-}
+def gitTagVersion = versionDetails()
+version = gitTagVersion.commitDistance == 0
+        ? gitTagVersion.lastTag
+        : "${gitTagVersion.lastTag}+${gitTagVersion.commitDistance}-SNAPSHOT"
 
 ext {
     springBootVersion = '2.4.0'
@@ -58,47 +48,26 @@ dependencies {
     testImplementation "org.springframework.security:spring-security-test"
 }
 
-bintray {
-    user = System.getenv('BINTRAY_USER')
-    key = System.getenv('BINTRAY_KEY')
-    publications = ['maven']
-    pkg {
-        repo = 'starterkit'
-        name = rootProject.name
-        userOrg = 'everestengineering'
-        licenses = ['Apache-2.0']
-        vcsUrl = 'https://github.com/everestengineering/starterkit-security'
+java {
+    java {
+        withJavadocJar()
+        withSourcesJar()
     }
-    publish = true
 }
 
-publishing {
-    publications {
-        maven(MavenPublication) {
-            from components.java
-        }
-    }
+repositories {
+    mavenCentral()
 }
 
-jacocoTestReport {
-    reports {
-        xml.enabled true
-        csv.enabled false
-        html.enabled true
-    }
+test {
+    useJUnitPlatform()
 }
 
-test.finalizedBy jacocoTestReport
-
-sonarqube {
-    properties {
-        property "sonar.projectName", "Lhotse - security"
-        property "sonar.projectKey", "everest-engineering_lhotse-security"
-        property "sonar.organization", "everestengineering"
-        property "sonar.host.url", "https://sonarcloud.io"
-        property 'sonar.test.exclusions', '**/*Test.java'
-    }
+lombok {
+    version = '1.18.16'
+    generateLombokConfig.enabled = false
+    config['lombok.addLombokGeneratedAnnotation'] = 'true'
 }
 
-tasks['sonarqube'].dependsOn test
-
+apply from: 'publishing.gradle'
+apply from: 'sonar.gradle'

publishing.gradle

@@ -0,0 +1,59 @@
+publishing {
+    publications {
+        release(MavenPublication) {
+            from components.java
+
+            pom {
+                name = 'lhotse-security'
+                description = 'This is a supporting library for Lhotse, a starter kit for writing event sourced web applications following domain driven design principles.'
+                url = 'https://github.com/everest-engineering/lhotse-security'
+                licenses {
+                    license {
+                        name = 'The Apache License, Version 2.0'
+                        url = 'http://www.apache.org/licenses/LICENSE-2.0.txt'
+                    }
+                }
+                developers {
+                    developer {
+                        id = 'everest-engineering'
+                        name = 'EverestEngineering'
+                        email = 'hi@everest.engineering'
+                    }
+                }
+                scm {
+                    connection = 'https://github.com/everest-engineering/lhotse-security.git'
+                    developerConnection = 'https://github.com/everest-engineering/lhotse-security.git'
+                    url = 'https://github.com/everest-engineering/lhotse-security'
+                }
+            }
+        }
+    }
+    repositories {
+        maven {
+            name = "MavenCentral"
+            def ossrhUsername = System.getenv('OSSRH_USERNAME')
+            def ossrhPassword = System.getenv('OSSRH_PASSWORD')
+            def releasesRepoUrl = 'https://s01.oss.sonatype.org/service/local/staging/deploy/maven2/'
+            def snapshotsRepoUrl = 'https://s01.oss.sonatype.org/content/repositories/snapshots/'
+            url = version.contains('SNAPSHOT') ? snapshotsRepoUrl : releasesRepoUrl
+
+            credentials {
+                username = "${ossrhUsername}"
+                password = "${ossrhPassword}"
+            }
+        }
+    }
+}
+
+signing {
+    def signingPassword = System.getenv('SIGNING_PASSWORD')
+    def signingKey = System.getenv('SIGNING_KEY')
+    useInMemoryPgpKeys(signingKey, signingPassword)
+    sign publishing.publications.release
+}
+
+javadoc {
+    if (JavaVersion.current().isJava9Compatible()) {
+        options.addBooleanOption('html5', true)
+    }
+}

sonar.gradle

@@ -0,0 +1,20 @@
+jacocoTestReport {
+    reports {
+        xml.enabled true
+        html.enabled true
+    }
+}
+
+test.finalizedBy jacocoTestReport
+
+sonarqube {
+    properties {
+        property 'sonar.projectName', 'Lhotse - security'
+        property 'sonar.projectKey', 'everest-engineering_lhotse-security'
+        property 'sonar.organization', 'everestengineering'
+        property 'sonar.host.url', 'https://sonarcloud.io'
+        property 'sonar.test.exclusions', '**/*Test.java'
+    }
+}
+
+tasks['sonarqube'].dependsOn test