Added Monitor and Slave mode support

Added examples: OpenThermMaster_Demo.ino, OpenThermMonitor_Demo.ino, OpenThermSlave_Demo.ino

isCentralHeatingEnabled, isHotWaterEnabled, isCoolingEnabled renamed to isCentralHeatingActive, isHotWaterActive, isCoolingActive

Author: ihormelnyk

examples/OpenThermMaster_Demo/OpenThermMaster_Demo.ino

@@ -0,0 +1,74 @@
+/*
+OpenTherm Master Communication Example
+By: Ihor Melnyk
+Date: January 19th, 2018
+
+Uses the OpenTherm library to get/set boiler status and water temperature
+Open serial monitor at 115200 baud to see output.
+
+Hardware Connections (OpenTherm Adapter (http://ihormelnyk.com/pages/OpenTherm) to Arduino/ESP8266):
+-OT1/OT2 = Boiler X1/X2
+-VCC = 5V or 3.3V
+-GND = GND
+-IN  = Arduino (3) / ESP8266 (5) Output Pin
+-OUT = Arduino (2) / ESP8266 (4) Input Pin
+
+Controller(Arduino/ESP8266) input pin should support interrupts.
+Arduino digital pins usable for interrupts: Uno, Nano, Mini: 2,3; Mega: 2, 3, 18, 19, 20, 21
+ESP8266: Interrupts may be attached to any GPIO pin except GPIO16,
+but since GPIO6-GPIO11 are typically used to interface with the flash memory ICs on most esp8266 modules, applying interrupts to these pins are likely to cause problems
+*/
+
+
+#include <Arduino.h>
+#include <OpenTherm.h>
+
+const int inPin = 2; //4 for ESP8266
+const int outPin = 3; //5 dor ESP8266
+OpenTherm ot(inPin, outPin);
+
+void handleInterrupt() {
+    ot.handleInterrupt();
+}
+
+void setup()
+{
+    Serial.begin(9600);
+    Serial.println("Start");
+
+    ot.begin(handleInterrupt);
+}
+
+void loop()
+{
+    //Set/Get Boiler Status
+    bool enableCentralHeating = true;
+    bool enableHotWater = true;
+    bool enableCooling = false;
+    unsigned long response = ot.setBoilerStatus(enableCentralHeating, enableHotWater, enableCooling);
+    OpenThermResponseStatus responseStatus = ot.getLastResponseStatus();
+    if (responseStatus == OpenThermResponseStatus::SUCCESS) {
+        Serial.println("Central Heating: " + String(ot.isCentralHeatingActive(response) ? "on" : "off"));
+        Serial.println("Hot Water: " + String(ot.isHotWaterActive(response) ? "on" : "off"));
+        Serial.println("Flame: " + String(ot.isFlameOn(response) ? "on" : "off"));
+    }
+    if (responseStatus == OpenThermResponseStatus::NONE) {
+        Serial.println("Error: OpenTherm is not initialized");
+    }
+    else if (responseStatus == OpenThermResponseStatus::INVALID) {
+        Serial.println("Error: Invalid response " + String(response, HEX));
+    }
+    else if (responseStatus == OpenThermResponseStatus::TIMEOUT) {
+        Serial.println("Error: Response timeout");
+    }
+
+    //Set Boiler Temperature to 64 degrees C
+    ot.setBoilerTemperature(64);
+
+    //Get Boiler Temperature
+    float temperature = ot.getBoilerTemperature();
+    Serial.println("Boiler temperature is " + String(temperature) + " degrees C");
+
+    Serial.println();
+    delay(1000);
+}

examples/OpenThermMonitor_Demo/OpenThermMonitor_Demo.ino

@@ -0,0 +1,47 @@
+/*
+OpenTherm Monitor Example
+By: Ihor Melnyk
+Date: May 1st, 2019
+*/
+
+
+#include <Arduino.h>
+#include <OpenTherm.h>
+
+const int mInPin = 4; //ESP8266
+const int mOutPin = 5;  //ESP8266
+
+const int sInPin = 12;  //ESP8266
+const int sOutPin = 13;  //ESP8266
+
+OpenTherm mOT(mInPin, mOutPin);
+OpenTherm sOT(sInPin, sOutPin, true);
+
+void mHandleInterrupt() {
+    mOT.handleInterrupt();
+}
+
+void sHandleInterrupt() {
+    sOT.handleInterrupt();
+}
+
+void processRequest(unsigned long request, OpenThermResponseStatus status) {
+    Serial.println("T" + String(request, HEX));  //master/thermostat request
+    unsigned long response = mOT.sendRequest(request);
+    if (response) {
+        Serial.println("B" + String(response, HEX)); //slave/boiler response
+        sOT.sendResponse(response);
+    }
+}
+
+void setup()
+{
+    Serial.begin(9600);	//9600 supported by OpenTherm Monitor App
+    mOT.begin(mHandleInterrupt);
+    sOT.begin(sHandleInterrupt, processRequest);
+}
+
+void loop()
+{
+    sOT.process();
+}

examples/OpenThermSlave_Demo/OpenThermSlave_Demo.ino

@@ -0,0 +1,42 @@
+/*
+OpenTherm Slave Example
+By: Ihor Melnyk
+Date: May 1st, 2019
+*/
+
+#include <Arduino.h>
+#include <OpenTherm.h>
+
+const int inPin = 12; //ESP8266
+const int outPin = 13; //ESP8266
+OpenTherm ot(inPin, outPin, true);
+
+void handleInterrupt() {
+    ot.handleInterrupt();
+}
+
+void processRequest(unsigned long request, OpenThermResponseStatus status) {
+    //receive request
+    Serial.println("T" + String(request, HEX)); //master/thermostat request
+
+    //build UNKNOWN-DATAID response
+    unsigned long response = ot.buildResponse(OpenThermMessageType::UNKNOWN_DATA_ID, ot.getDataID(request), 0);
+
+    //send response
+    ot.sendResponse(response);
+    Serial.println("B" + String(response, HEX)); //slave/boiler response
+}
+
+void setup()
+{
+    Serial.begin(9600);
+    Serial.println("Start");
+
+    ot.begin(handleInterrupt, processRequest);
+}
+
+
+void loop()
+{
+    ot.process();
+}