Port DirectAccess feature from Wallet to TestApp.

- Wallet DirectAccess code ported into multipaz.directaccess module.
- Refactored to avoid APDU initialization lock up (removed runBlocking calls).
- Removed explicit document slot handling in favor of automatic handling as there is only one slot available so far.
- Improved APDU calling logic to avoid calls without requesting document slot.

Test: All Unit tests are passing (bar KI).
Test: Manually tested via samples/testapp on Android and iOS.

Signed-off-by: koukarine <koukarine@google.com>

Author: koukarine

gradle/libs.versions.toml

@@ -9,6 +9,7 @@ androidx-core-ktx = "1.16.0"
 androidx-espresso-core = "3.7.0"
 androidx-material = "1.12.0"
 androidx-test-junit = "1.3.0"
+annotation = "1.9.1"
 compose-plugin = "1.8.2"
 faceDetection = "16.1.7"
 junit = "4.13.2"
@@ -59,6 +60,7 @@ litertMetadata = "1.4.0"
 litertSupport = "1.4.0"
 
 [libraries]
+androidx-annotation = { module = "androidx.annotation:annotation", version.ref = "annotation" }
 androidx-ui-tooling-preview = { module = "androidx.compose.ui:ui-tooling-preview", version.ref = "uiToolingPreview" }
 face-detection = { module = "com.google.mlkit:face-detection", version.ref = "faceDetection" }
 kotlin-test = { module = "org.jetbrains.kotlin:kotlin-test", version.ref = "kotlin" }

multipaz-directaccess/.gitignore

@@ -0,0 +1 @@
+/build

multipaz-directaccess/build.gradle.kts

@@ -0,0 +1,127 @@
+import org.jetbrains.kotlin.gradle.ExperimentalKotlinGradlePluginApi
+import org.jetbrains.kotlin.gradle.dsl.JvmTarget
+import org.jetbrains.kotlin.gradle.plugin.KotlinSourceSetTree
+
+plugins {
+    alias(libs.plugins.kotlinMultiplatform)
+    alias(libs.plugins.androidLibrary)
+    id("maven-publish")
+}
+
+val projectVersionName: String by rootProject.extra
+
+kotlin {
+    jvmToolchain(17)
+
+    androidTarget {
+        @OptIn(ExperimentalKotlinGradlePluginApi::class)
+        instrumentedTestVariant.sourceSetTree.set(KotlinSourceSetTree.test)
+
+        @OptIn(ExperimentalKotlinGradlePluginApi::class)
+        compilerOptions {
+            jvmTarget.set(JvmTarget.JVM_17)
+        }
+
+        publishLibraryVariants("release")
+    }
+
+    listOf(
+        iosX64(),
+        iosArm64(),
+        iosSimulatorArm64()
+    ).forEach {
+        val platform = when (it.name) {
+            "iosX64" -> "iphonesimulator"
+            "iosArm64" -> "iphoneos"
+            "iosSimulatorArm64" -> "iphonesimulator"
+            else -> error("Unsupported target ${it.name}")
+        }
+        it.binaries.all {
+            linkerOpts(
+                "-L/Applications/Xcode.app/Contents/Developer/Toolchains/XcodeDefault.xctoolchain/usr/lib/swift/${platform}/",
+            )
+        }
+    }
+
+    sourceSets {
+        val commonMain by getting {
+            dependencies {
+                implementation(project(":multipaz"))
+            }
+        }
+
+        val commonTest by getting {
+            dependencies {
+                implementation(libs.kotlin.test)
+                implementation(libs.kotlinx.coroutines.test)
+            }
+        }
+
+        val androidMain by getting {
+            dependencies {
+                implementation(project(":multipaz"))
+                implementation(libs.androidx.annotation)
+                implementation(libs.kotlinx.datetime)
+                implementation(libs.kotlinx.io.bytestring)
+                implementation(libs.kotlinx.serialization.json)
+                implementation(libs.bouncy.castle.bcprov)
+
+                api(project(":multipaz"))
+            }
+        }
+    }
+}
+
+android {
+    namespace = "org.multipaz.mlkit"
+    compileSdk = libs.versions.android.compileSdk.get().toInt()
+
+    defaultConfig {
+        minSdk = 26
+        testInstrumentationRunner = "androidx.test.runner.AndroidJUnitRunner"
+    }
+
+    compileOptions {
+        sourceCompatibility = JavaVersion.VERSION_17
+        targetCompatibility = JavaVersion.VERSION_17
+    }
+    dependencies {
+        debugImplementation(libs.androidx.ui.tooling.preview)
+        androidTestImplementation(libs.compose.junit4)
+        debugImplementation(libs.compose.test.manifest)
+    }
+
+    packaging {
+        resources {
+            excludes += listOf("/META-INF/{AL2.0,LGPL2.1}")
+            excludes += listOf("/META-INF/versions/9/OSGI-INF/MANIFEST.MF")
+        }
+    }
+
+    publishing {
+        singleVariant("release") {
+            withSourcesJar()
+        }
+    }
+}
+
+group = "org.multipaz"
+version = projectVersionName
+
+publishing {
+    repositories {
+        maven {
+            url = uri("${rootProject.rootDir}/repo")
+        }
+    }
+    publications.withType(MavenPublication::class) {
+        pom {
+            licenses {
+                license {
+                    name = "Apache 2.0"
+                    url = "https://opensource.org/licenses/Apache-2.0"
+                }
+            }
+        }
+    }
+}

multipaz-directaccess/src/androidMain/AndroidManifest.xml

@@ -0,0 +1,4 @@
+<?xml version="1.0" encoding="utf-8"?>
+<manifest xmlns:android="http://schemas.android.com/apk/res/android">
+
+</manifest>