Merge pull request #382 from AshFungor/different-cmake-layout

Restructure CMake project layout: make interacting with Artery's options and dependencies easier

Author: riebl

.github/workflows/lint.yaml

@@ -19,7 +19,12 @@ jobs:
           fetch-depth: 0
 
       - name: Configure CMake
-        run: tools/build.py -cl
+        run: |
+          tools/build.py -cl              \
+            -D WITH_SIMULTE:BOOL=ON       \
+            -D WITH_OTS:BOOL=ON           \
+            -D WITH_TESTBED:BOOL=ON       \
+            -D WITH_TRANSFUSION:BOOL=ON
 
       - name: Run clang-tidy
         run: |

.github/workflows/test.yaml

@@ -16,6 +16,7 @@ jobs:
       - uses: actions/checkout@v5
         with:
           submodules: recursive
+          fetch-depth: 0
 
       - name: Create virtual environment
         run: python3 -m venv .venv
@@ -24,7 +25,11 @@ jobs:
         run: . .venv/bin/activate && pip install -r tools/ci/requirements.txt
 
       - name: Configure and build CMake
-        run: tools/build.py -cb --config Release --generator Ninja
+        run: |
+          tools/build.py -cb --config Release \
+            --generator Ninja                 \
+            -D WITH_SIMULTE:BOOL=ON           \
+            -D WITH_OTS:BOOL=ON
 
       - name: Run tests
         run: . .venv/bin/activate && PYTHONPATH=$PWD python3 tools/ci/run.py -l build/Release/run-artery.ini -s scenarios

CMakeLists.txt

@@ -1,21 +1,40 @@
 cmake_minimum_required(VERSION 3.16)
+
 cmake_policy(VERSION 3.16...3.31)
-project(Artery)
 
-set(CMAKE_MODULE_PATH ${PROJECT_SOURCE_DIR}/cmake)
+project(Artery LANGUAGES CXX C)
+
+enable_testing()
+
 set(CMAKE_CXX_STANDARD 17)
 set(CMAKE_CXX_STANDARD_REQUIRED ON)
-enable_testing()
+set(CMAKE_CXX_EXTENSIONS OFF)
 
-find_package(OmnetPP 5.5.1 MODULE REQUIRED)
-include(AddOppRun)
-include(AddOppTarget)
-include(AddVSCode)
-include(CheckGitSubmodule)
-include(GenerateOppMessage)
-include(GNUInstallDirs)
+list(APPEND CMAKE_MODULE_PATH ${PROJECT_SOURCE_DIR}/cmake)
 
-find_package(Boost 1.59 REQUIRED COMPONENTS date_time system CONFIG)
+##################
+# Artery Options #
+##################
+
+# These are essential componets that are better to be turned on.
+option(WITH_INET "Build Artery with INET framework integration" ON)
+option(WITH_VEINS "Build Artery with Veins framework integration" ON)
+
+# Various extensions, adjust them as needed.
+option(WITH_SIMULTE "Build Artery with SimuLTE integration" OFF)
+option(WITH_OTS "Build Artery with support for OpenTrafficSim" OFF)
+option(WITH_TESTBED "Build Artery with testbed feature" OFF)
+option(WITH_ENVMOD "Build Artery with environment model feature" ON)
+option(WITH_STORYBOARD "Build Artery with storyboard feature" ON)
+option(WITH_TRANSFUSION "Build Artery with transfusion feature" OFF)
+
+# Miscellaneous stuff, does not affect functionality directly.
+option(WITH_SCENARIOS "Build Artery with scenarios" ON)
+option(VSCODE_LAUNCH_INTEGRATION "Generate VS Code configuration for debugging Artery (requires debug build)" OFF)
+
+##############################
+# Artery build configuration #
+##############################
 
 # use "RelWithDebInfo" as default build type
 if(NOT CMAKE_BUILD_TYPE AND NOT CMAKE_CONFIGURATION_TYPES)
@@ -26,83 +45,76 @@ endif()
 # running simulations with opp_run requires shared libraries
 set(BUILD_SHARED_LIBS ON CACHE INTERNAL "Cached for propagation to sub-projects with older CMake versions")
 
-check_git_submodule(PATH extern/vanetza REQUIRED_FILES CMakeLists.txt)
-set(VANETZA_INSTALL ON)
-add_subdirectory(${PROJECT_SOURCE_DIR}/extern/vanetza)
-mark_as_advanced(BUILD_BENCHMARK BUILD_CERTIFY BUILD_SOCKTAP BUILD_TESTS BUILD_USING_CONAN)
-mark_as_advanced(VANETZA_ASN1_WITH_ASN1C VANETZA_EXPORT_PACKAGE VANETZA_NET_WITH_POSIX)
-
-check_git_submodule(PATH extern/veins REQUIRED_FILES src/veins/package.ned)
-find_path(Veins_DIR NAMES src/veins/package.ned PATHS extern/veins DOC "Veins root directory")
-mark_as_advanced(Veins_DIR)
-add_opp_target(TARGET veins ROOT_DIR ${Veins_DIR})
-
-
-check_git_submodule(PATH extern/inet REQUIRED_FILES src/inet/package.ned)
-find_path(INET_DIR NAMES src/inet/package.ned PATHS extern/inet DOC "INET root directory")
-mark_as_advanced(INET_DIR)
-set_property(DIRECTORY APPEND PROPERTY CMAKE_CONFIGURE_DEPENDS ${INET_DIR}/.oppfeaturestate ${INET_DIR}/.nedexclusions)
-
-# collect INET's opp_makemake options
-execute_process(COMMAND ./inet_featuretool options -l -f
-    WORKING_DIRECTORY ${INET_DIR}
-    OUTPUT_VARIABLE INET_OPP_MAKEMAKE)
-separate_arguments(INET_OPP_MAKEMAKE UNIX_COMMAND ${INET_OPP_MAKEMAKE})
-
-# generate INET's features and opp_defines header
-set(INET_GEN_DIR ${PROJECT_BINARY_DIR}/INET_gen)
-file(MAKE_DIRECTORY ${INET_GEN_DIR}/inet)
-add_custom_command(OUTPUT ${INET_DIR}/.oppfeaturestate
-    COMMAND ./inet_featuretool repair
-    DEPENDS ${INET_DIR}/.oppfeatures ${INET_DIR}/inet_featuretool
-    WORKING_DIRECTORY ${INET_DIR})
-add_custom_command(OUTPUT ${INET_GEN_DIR}/inet/features.h
-    COMMAND ./inet_featuretool defines >${INET_GEN_DIR}/inet/features.h
-    DEPENDS ${INET_DIR}/.oppfeaturestate
-    WORKING_DIRECTORY ${INET_DIR}
-    COMMENT "Generate INET features.h")
-add_custom_command(OUTPUT ${INET_GEN_DIR}/inet/opp_defines.h
-    COMMAND ${CMAKE_COMMAND} -E touch ${INET_GEN_DIR}/inet/opp_defines.h
-    COMMENT "Generate INET opp_defines.h")
-
-add_opp_target(TARGET INET ROOT_DIR ${INET_DIR}
-    DEPENDS ${INET_GEN_DIR}/inet/features.h ${INET_GEN_DIR}/inet/opp_defines.h
-    OPP_MAKEMAKE ${INET_OPP_MAKEMAKE})
-
-
-check_git_submodule(PATH extern/simulte REQUIRED_FILES src/package.ned)
-find_path(SimuLTE_DIR NAMES src/package.ned PATHS extern/simulte DOC "SimuLTE root directory")
-mark_as_advanced(SimuLTE_DIR)
-option(WITH_SIMULTE "Build Artery with SimuLTE integration" OFF)
-if(WITH_SIMULTE)
-    add_opp_target(TARGET lte ROOT_DIR ${SimuLTE_DIR})
-    target_link_libraries(lte PUBLIC INET)
-else()
-    message(STATUS "SimuLTE integration disabled")
-endif()
+###############################
+# Required packages & scripts #
+###############################
 
+find_package(OmnetPP 5.5.1 MODULE REQUIRED)
+find_package(Boost 1.59 REQUIRED COMPONENTS date_time system CONFIG)
 
-option(WITH_ENVMOD "Build Artery with environment model feature" ON)
-option(WITH_STORYBOARD "Build Artery with storyboard feature" ON)
-option(WITH_TRANSFUSION "Build Artery with transfusion feature" OFF)
-option(WITH_TESTBED "Build Artery with testbed feature" OFF)
+include(AddOppRun)
+include(AddOppTarget)
+include(AddVSCode)
+include(CheckGitSubmodule)
+include(GenerateOppMessage)
+include(AddArterySubdirectory)
+include(GNUInstallDirs)
 
-option(WITH_OTS "Build Artery with support for OpenTrafficSim" OFF)
-if(WITH_OTS)
-    add_subdirectory(src/ots)
+# Packages below are needed by various
+# optional components. They should be used
+# with add_artery_subdirectory() to trigger
+# checks on them only if variables (WITH*)
+# are set.
+
+find_package(Protobuf QUIET)
+find_package(PkgConfig MODULE QUIET)
+find_package(SEA_V2X CONFIG QUIET)
+
+if(PkgConfig_FOUND)
+    pkg_check_modules(ZEROMQ QUIET IMPORTED_TARGET libzmq)
 endif()
-add_subdirectory(src/traci)
 
+if(SEA_V2X_FOUND)
+    mark_as_advanced(SEA_V2X_DIR)
+endif()
+
+add_subdirectory(extern)
+
+##########################
+# Primary Artery targets #
+##########################
+
+# TODO: temporarily targets are moved into src/artery
+
+macro(add_artery_feature name)
+    add_library(${name} SHARED ${ARGN})
+    add_library(Artery::${name} ALIAS ${name})
+    get_target_property(ned_folder ${name} SOURCE_DIR)
+    set_target_properties(${name} PROPERTIES
+        OUTPUT_NAME artery_${name}
+        OMNETPP_LIBRARY ON
+        NED_FOLDERS ${ned_folder})
+    target_link_libraries(${name} PRIVATE core)
+    target_link_libraries(artery INTERFACE Artery::${name})
+    install(TARGETS ${name} LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR})
+endmacro()
+
+##########
+# Artery #
+##########
+
+add_subdirectory(src/traci)
 add_subdirectory(src/artery)
 
-option(VSCODE_LAUNCH_INTEGRATION "Generate VS Code configuration for debugging Artery (requires debug build)" OFF)
+add_artery_subdirectory(src/ots REQUIRES INET PkgConfig::ZEROMQ SWITCH WITH_OTS)
 
 # scenarios directory is part of repository but omitted for Docker build context
-if(EXISTS ${PROJECT_SOURCE_DIR}/scenarios)
+if(WITH_SCENARIOS)
     add_subdirectory(scenarios)
 endif()
 
 get_property(is_multi_config GLOBAL PROPERTY GENERATOR_IS_MULTI_CONFIG)
+
 if(is_multi_config)
     foreach(config IN LISTS CMAKE_CONFIGURATION_TYPES)
         string(TOLOWER "${config}" config_lower)
@@ -113,3 +125,13 @@ else()
     generate_run_config(TARGET artery CONFIG ${CMAKE_BUILD_TYPE} FILE "${PROJECT_BINARY_DIR}/run-artery.ini")
     generate_run_config(TARGET artery CONFIG ${CMAKE_BUILD_TYPE} FILE "${PROJECT_BINARY_DIR}/run-artery.ini.install" INSTALL)
 endif()
+
+if(VSCODE_LAUNCH_INTEGRATION)
+    if(is_multi_config AND "Debug" NOT IN CMAKE_CONFIGURATION_TYPES)
+        message(STATUS "VS Code integration is enabled, but Debug is not included in build types")
+    elseif(NOT "${CMAKE_BUILD_TYPE}" STREQUAL "Debug")
+        message(STATUS "VS Code integration is enabled, but build type is not Debug")
+    else()
+        generate_vscode(TARGET artery FILE ${PROJECT_SOURCE_DIR}/.vscode/launch.json)
+    endif()
+endif()

cmake/AddArterySubdirectory.cmake

@@ -0,0 +1,36 @@
+function(add_artery_subdirectory directory)
+    # include target subdirectory with certain artery
+    # extension (feature), if the following conditions match:
+    # 1) variable with id matching SWITCH is set to true (feature turned on)
+    # 2) targets that are listed in REQUIRES are declared (exist by their provided names)
+
+    # If condition 1) is not met, then subdirectory is not added and
+    # debug message is issued. If one or more targets specified by REQUIRES does not exist,
+    # this function raises error. Note: these checks are not meant to determine if package
+    # was loaded correctly, but rather to make feature-to-package relation verbose in CMake files.
+
+    set(one_value_args SWITCH)
+    set(multi_value_args REQUIRES)
+    cmake_parse_arguments(args "" "${one_value_args}" "${multi_value_args}" ${ARGN})
+
+    if(args_UNPARSED_ARGUMENTS)
+        message(SEND_ERROR "add_artery_subdirectory called with invalid arguments: ${args_UNPARSED_ARGUMENTS}")
+    endif()
+
+    if(NOT ${${args_SWITCH}})
+        message(STATUS "add_artery_subdirectory: skipping ${directory} (switched off)")
+    else()
+        message(STATUS "add_artery_subdirectory: adding ${directory} (switched on)")
+
+        foreach(required_target IN LISTS args_REQUIRES)
+            if(NOT TARGET ${required_target})
+                message(
+                    FATAL_ERROR
+                    "add_artery_subdirectory: required target '${required_target}' for '${directory}' does not exist"
+                )
+            endif()
+        endforeach()
+
+        add_subdirectory("${directory}")
+    endif()
+endfunction()

cmake/GenerateOppMessage.cmake

@@ -10,6 +10,7 @@ function(generate_opp_message msg_input)
     set(msg_output_root ${PROJECT_BINARY_DIR}/opp_messages)
     get_filename_component(msg_name "${msg_input}" NAME_WE)
     get_filename_component(msg_dir "${msg_input}" DIRECTORY)
+
     if(args_DIRECTORY)
         set(msg_prefix "${args_DIRECTORY}")
     else()

extern/CMakeLists.txt

@@ -0,0 +1,98 @@
+check_git_submodule(PATH vanetza REQUIRED_FILES CMakeLists.txt)
+set(VANETZA_INSTALL ON)
+
+add_subdirectory(vanetza)
+mark_as_advanced(
+    BUILD_BENCHMARK
+    BUILD_CERTIFY
+    BUILD_SOCKTAP
+    BUILD_TESTS
+    BUILD_USING_CONAN
+    VANETZA_ASN1_WITH_ASN1C
+    VANETZA_EXPORT_PACKAGE
+    VANETZA_NET_WITH_POSIX
+)
+
+if(WITH_VEINS)
+    message(STATUS "Enable Veins integration")
+    check_git_submodule(PATH veins REQUIRED_FILES src/veins/package.ned)
+
+    find_path(Veins_DIR NAMES src/veins/package.ned PATHS veins DOC "Veins root directory")
+    mark_as_advanced(Veins_DIR)
+    add_opp_target(TARGET veins ROOT_DIR ${Veins_DIR})
+endif()
+
+if(WITH_INET)
+    message(STATUS "Enable INET integration")
+
+    check_git_submodule(PATH inet REQUIRED_FILES src/inet/package.ned)
+    find_path(INET_DIR NAMES src/inet/package.ned PATHS inet DOC "INET root directory")
+    mark_as_advanced(INET_DIR)
+
+    set_property(DIRECTORY APPEND PROPERTY CMAKE_CONFIGURE_DEPENDS ${INET_DIR}/.oppfeaturestate ${INET_DIR}/.nedexclusions)
+
+    # collect INET's opp_makemake options
+    execute_process(
+        COMMAND ./inet_featuretool options -l -f
+        WORKING_DIRECTORY ${INET_DIR}
+        OUTPUT_VARIABLE INET_OPP_MAKEMAKE
+    )
+    separate_arguments(INET_OPP_MAKEMAKE UNIX_COMMAND ${INET_OPP_MAKEMAKE})
+    
+    # generate INET's features and opp_defines header
+    set(INET_GEN_DIR ${PROJECT_BINARY_DIR}/INET_gen)
+    file(MAKE_DIRECTORY ${INET_GEN_DIR}/inet)
+
+    add_custom_command(
+        OUTPUT ${INET_DIR}/.oppfeaturestate
+        COMMAND ./inet_featuretool repair
+        DEPENDS ${INET_DIR}/.oppfeatures ${INET_DIR}/inet_featuretool
+        WORKING_DIRECTORY ${INET_DIR}
+    )
+
+    add_custom_command(
+        OUTPUT ${INET_GEN_DIR}/inet/features.h
+        COMMAND ./inet_featuretool defines >${INET_GEN_DIR}/inet/features.h
+        DEPENDS ${INET_DIR}/.oppfeaturestate
+        WORKING_DIRECTORY ${INET_DIR}
+        COMMENT "Generate INET features.h"
+    )
+
+    add_custom_command(
+        OUTPUT ${INET_GEN_DIR}/inet/opp_defines.h
+        COMMAND ${CMAKE_COMMAND} -E touch ${INET_GEN_DIR}/inet/opp_defines.h
+        COMMENT "Generate INET opp_defines.h"
+    )
+    
+    add_opp_target(
+        TARGET INET ROOT_DIR ${INET_DIR}
+        DEPENDS ${INET_GEN_DIR}/inet/features.h ${INET_GEN_DIR}/inet/opp_defines.h
+        OPP_MAKEMAKE ${INET_OPP_MAKEMAKE}
+    )
+endif()
+
+if(WITH_SIMULTE)
+    message(STATUS "Enable SimuLTE integration")
+    if(NOT TARGET INET)
+        message(FATAL_ERROR "SimuLTE requires INET")
+    endif()
+
+    check_git_submodule(PATH simulte REQUIRED_FILES src/package.ned)
+    find_path(SimuLTE_DIR NAMES src/package.ned PATHS simulte DOC "SimuLTE root directory")
+    mark_as_advanced(SimuLTE_DIR)
+
+    add_opp_target(TARGET lte ROOT_DIR ${SimuLTE_DIR})
+    target_link_libraries(lte PUBLIC INET)
+else()
+    message(STATUS "SimuLTE integration disabled")
+endif()
+
+if(WITH_STORYBOARD)
+    add_subdirectory(pybind11)
+endif()
+
+if(WITH_OTS)
+    set(SIM0MQPP_INSTALL ON)
+    set(SIM0MQPP_SHARED_LIB ON)
+    add_subdirectory(sim0mqpp ${PROJECT_BINARY_DIR}/sim0mqpp)
+endif()