Add PKGBUILD for Arch Linux users

Author: scotow

PKGBUILD

@@ -0,0 +1,35 @@
+# Maintainer: Benjamin Lopez <contact@scotow.com>
+
+pkgname=mego
+pkgver=1.0.3
+pkgrel=1
+pkgdesc="A simple megadl wrapper with auto-retry and download list"
+arch=('x86_64')
+url="https://github.com/scotow/${pkgname}"
+license=('MIT')
+depends=('megatools')
+makedepends=('go' 'git')
+source=("${pkgname}-${pkgver}.tar.gz::https://github.com/scotow/${pkgname}/archive/${pkgver}.tar.gz")
+sha256sums=('7b952705c25e06c25f82c2c76c20c34e45b2487e4af1ff7bf39ae22daeed8407')
+
+prepare(){
+  mkdir -p src/github.com/scotow
+  ln -rTsf "${pkgname}-${pkgver}" "src/github.com/scotow/${pkgname}"
+}
+
+build(){
+  export GOPATH="${srcdir}"
+  cd "src/github.com/scotow/${pkgname}"
+  go install \
+	-gcflags "all=-trimpath=${GOPATH}/src" \
+	-asmflags "all=-trimpath=${GOPATH}/src" \
+	-ldflags "-extldflags ${LDFLAGS}" \
+	./...
+}
+
+package(){
+  install -Dm755 "bin/${pkgname}" "${pkgdir}/usr/bin/${pkgname}"
+
+  cd "${pkgname}-${pkgver}"
+  install -Dm644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+}